Obras, reformas, métodos de construcción, etc.
por
#355217
Buenas! Estoy realizando un proyecto de una pasarela peatonal que se basa en una estructura mixta, tiene un tubo estructural de acero, el cual soportará sobre él el tablero de hormigón armado sobre el que se podrán pasar tanto peatones como ciclistas. Para realizar el modelado de esta estructura, de la cual ya tengo el modelo, ¿cómo puedo hacerlo mediante el programa ANSYS?

Espero podáis ayudarme, saludos!
por
#359070
Buenas.

LO primero que he de decirte que ANSYS no es un software sencillo de utilizar. Yo he realizado bastantes cálculos. Este programa no dimensiona. Por lo que los materiales, secciones, etc debes saberlos. tener realizado un pre-calculo.
ANSYS hoy en día utiliza un nuevo shell denominado Workbench, pero yo sigo utilizando el APDL.

En unas lineas es bastante complicado explicarte como se modela en ANSYS.
El modelado de ANSYS se puede definir en varias etapas, yo lo hago asi para tenerlo todo ordenado.
1. definición de los elementos.
2. dibujo del modelo.
3. mallado del modelo.
4. aplicación de cargas.
5. tipo de resolución, estructural, modal, espectral.

1. se define que tipo de elementos vas a utilizar en la resolución del problemas, si lo vas a hacer en 2d o 3d, veo que pones que con barras, para este tipo de elementos puedes utilizar un beam. (2d o 3d), pero tambien por lo que explicas vas a tener shell, la superficie de paso.
2. Dibujar como es tu estructura.
3. Mallar la estructura.

Y así cada punto, yo normalmente lo realizo mediante texto, no en pantalla, para mi es mucho mas cómodo. te puedo poner un ejemplo de un deposito que hice, para su calculo modal y espectral, es decir, comportamiento ante un sismo.

FINISH
/CLEAR
/FILENAME,DEPOSCIL3DC,1
/TITLE,DEPOSCIL3DC
/PREP7
CSYS,1
*AFUN,DEG !UNIDADES ANGULARES EN GRADOS
/VUP,,Z !EJE Z EN LA VERTICAL
!
!----------UNIDADES----------
!
!LONGITUD M
!TIEMPO S
!ACELERACIÓN M/S2
!DENSIDAD KG/M3
!FUERZA N
!ESFUERZO N/M2
!
!----------CONSTANTES O VARIABLES----------
!
G = 9.81 !ACELERACIÓN DE GRAVEDAD
H1=3 !ALTURA DEL LIQUIDO
H2 = 6 !ALTURA TOTAL DEL DEPOSITO
DIAM = 8 !DIÁMETRO DEL FLUIDO
RAD = DIAM/2 !RADIO DEL FLUIDO
PS = 7850 !DENSIDAD DE MASA DEL ACERO
ES = 206E9 !MODULO DE ELASTICIDAD DEL ACERO (METIDO EN PA(N/M2)
PW = 1000 !DENSIDAD DE MASA DEL AGUA
CW = 1483 !VELOCIDAD DEL SONIDO AGUA M/S
TAMEL=0.26 !TAMAÑO ELEMENTO DEPOSITO
ESP=0.005 !ESPESOR
MODOS = 50 !NUMEROS DE MODOS
!
!--------PROPIEDADES MATERIALES--------
!
ET,1,FLUID30 !FLUIDO
MP,SONC,1,CW
MP,DENS,1,PW
R,1
!
ET,2,SHELL63 !DEPOSITO
MP,EX,2,ES
MP,PRXY,2,0.3
MP,DENS,2,PS
R,2,ESP
!
!---------DISEÑO FLUIDO------
!
CYL4,0,0,RAD,45
AGEN,8,1,,,,45
AGLUE,ALL
NUMMRG,KP
NUMCMO,ALL
ALLSEL
VEXT,ALL,,,,,-H1
VGLUE,ALL
NUMMRG,KP
NUMCMO,ALL
ALLSEL
!
!-------DISEÑO PARED DEL DEPOSITO-------
!
K,19,RAD,0,H2-H1
K,20,RAD,45,H2-H1
K,21,RAD,90,H2-H1
K,22,RAD,135,H2-H1
K,23,RAD,180,H2-H1
K,24,RAD,225,H2-H1
K,25,RAD,270,H2-H1
K,26,RAD,315,H2-H1
A,1,2,20,19
A,2,4,21,20
A,4,5,22,21
A,5,6,23,22
A,6,7,24,23
A,7,8,25,24
A,8,9,26,25
A,9,1,19,26
ASEL,S,,,33,40,1
AGLUE,ALL
NUMMRG,KP
NUMCMO,ALL
ALLSEL
!
! ------MALLADO DEL FLUIDO-----
!
TYPE,1
MAT,1
R,1
MSHAPE,0,3D
MSHKEY,1
AESIZE,ALL,TAMEL
VMESH,ALL
NSEL,S,,,ALL
CM,FLUIDO,NODE
ALLSEL
!
! ----------MALLADO DEPOSITO--------
!
TYPE,2
MAT,2
REAL,2
MSHAPE,0,3D
MSHKEY,1
ASEL,S,,,33,40,1
ASEL,A,,,14,32,3
ASEL,A,,,10
AESIZE,ALL,TAMEL
AMESH,ALL
ALLSEL
!
! ----------CONDICIONES DE CONTORNO----------
!
NSEL,S,LOC,Z,-H1 !NODOS DEL SUELO IMPIDO UX,UY,UZ
D,ALL,UX
D,ALL,UY
D,ALL,UZ
ALLSEL
NSEL,S,LOC,Z,0 !LAMINA DE AGUA CC LIBRE
SF,ALL,FREE
ALLSEL
CMSEL,S,FLUIDO !PAREDES DEL LIQUIDO CC FSI
NSEL,R,LOC,X,RAD
ESLN,S
ESEL,R,TYPE,,1
SF,ALL,FSI
ALLSEL
!
! ---------ANALISIS MODAL----------
!
/SOLU
ANTYPE,MODAL
ACEL,0,0,G
MODOPT,UNSYM,MODOS,18,40,,,both
MXPAND,MODOS,,,YES
/OUTPUT,DEP_LIQ3DC,TXT
SOLVE
/OUTPUT
SAVE
FINISH
!
! ----------ANALISIS ESPECTRAL----------
!
/SOLU
ANTYPE,SPECTRUM
SPOPT,SPRS
SVTYP,2,1
FREQ,0.13333,0.14286,0.18182,0.25,0.36364,0.5,0.8,1,1.33333
FREQ,2,10,12.5,20,33.33333,100,200
SV,0,0.06104,0.07007,0.1135,0.21459,0.31214,0.42919,0.68670,0.85838,1.1445
SV,0,1.71675,1.71675,1.51074,1.20173,0.99572,0.78971,0.73820
SED,1.0,0.0,0.0
SRSS
/OUTPUT,DEP_LIQ3DC,TXT,,APPEND
SOLVE
/OUTPUT
SAVE
FINISH
!
/POST1
RSYS,SOLU
/INPUT,DEPOSCIL3DC,MCOM
SAVE

NO es un programa, para meterte a utilizar si no lo has manejado antes.

Dime si te puedo ayudar en algo.

Un saludo

Palabras clave
Temas similares

Usuarios navegando por este Foro: No hay usuarios registrados visitando el Foro y 1 invitado

Permisos de mensaje

No puede abrir nuevos temas en este Foro
No puede responder a temas en este Foro
No puede editar sus mensajes en este Foro
No puede borrar sus mensajes en este Foro
No puede enviar adjuntos en este Foro